// return.txt
// Like basicnpc.txt, but it is placed to guard a certain area. If it gets
// too far from where it starts, will run back to start, even if it is in 
// combat.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The maximum distance it will go from start. If it's ever 
//     farther away, returns to start. If left at 0, max. distance defaults
//     to 8.

begincreaturescript;

variables;

short i,target;
short return_dist = 5;

body;

beginstate INIT_STATE;
	set_name(ME,"Vahnvoi Bladesmaster");
	set_level(ME,35);
	set_special_ability(ME,32);
	break;

beginstate DEAD_STATE;
	message_dialog("The undead finally falls to your hack-and-slash method.","Curiously enough, it leaves a key behind it. You decide to take it.");
	change_spec_item(1,1);
	break;

beginstate START_STATE; 
	if (my_dist_from_start() >= return_dist) 
		return_to_start(ME,2);

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if (my_dist_from_start() >= 6) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (my_dist_from_start() >= return_dist) {
		set_target(ME,-1);
		return_to_start(ME,2);
		set_state(START_STATE);
		}

	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	message_dialog("The undead says nothing.","All it's energy is being used to try to kill you.");
break;